#!/bin/csh

set autolist = ambiguous
unset autologout
set nobeep
set notify
set rmstar
set watch = (1 any any)

if ( ${?MAIL} != 0 ) then
  set mail = $MAIL
endif

if ( ${?prompt} != 0 ) then
  if ( "_$TERM" == "_xterm" ) then
    set prompt='%{\033]0;%B%n@%m%b:%~%#\007%}%B%n@%m%b:%~%# '
  else
    set prompt='%B%n@%m%b:%~%# '
  endif
endif

if ( ${?DISPLAY} == 0 ) then
  if ( ${?REMOTEHOST} != 0 ) then
    setenv DISPLAY	$REMOTEHOST\:0.0
  else if ( ${?SSH_CLIENT} != 0 ) then
    setenv DISPLAY	`echo "$SSH_CLIENT" | sed 's/ .*//'`:0.0
  endif
endif

set d = ( find . -type d )
set f = ( find . -type f ! -name .md5sum )
if ( `uname` == 'Linux' ) then
  set bc = ( bc -q )
  set i = -iname
  set h = `hostname -s`
  set f0 = -print0
  set x0 = -r0
else
  set bc = bc
  set i = -name
  set h = `hostname`
  set f0 = ''
  set x0 = ''
endif

alias bcxd	'echo "scale=3; ibase=16" > /tmp/bc.$$; '$bc' /tmp/bc.$$'
alias bcdx	'echo "obase=16" > /tmp/bc.$$; '$bc' /tmp/bc.$$'
alias bcxx	'echo "obase=16;ibase=16" > /tmp/bc.$$; '$bc' /tmp/bc.$$'

alias bcbd	'echo "scale=3; ibase=2" > /tmp/bc.$$; '$bc' /tmp/bc.$$'
alias bcdb	'echo "obase=2" > /tmp/bc.$$; '$bc' /tmp/bc.$$'
alias bcbb	'echo "obase=2;ibase=2" > /tmp/bc.$$; '$bc' /tmp/bc.$$'

alias back	'set back="$old"; set old="$cwd"; cd "$back"; unset back; dirs'
alias chownhome	'chown -R \!*.\!* \!*'
alias cd	'set old="$cwd"; chdir \!*'
alias cdl	'cd \!* && ls -l'
alias cfg	'./configure'
alias cfgh	'./configure --help|more'
alias cls	'clear'
alias dir	'lsl'
alias dus	'du -s *|sort -n;du -s .'
alias g		$f $f0' | xargs '$x0 grep
alias h		'history'
alias lsa       'ls -la'
alias lddw	'ldd `which \!*`'
alias ls	'ls -F'
alias lsl       'ls -l'
alias lst       'ls -lrt'
alias md        'mkdir'
alias mdc	'mkdir \!* && cd \!*'
alias mp	'mpg123 -q -b 4096 \!* &'
alias mpa	'mpg123 -q -b 4096 \!* *.mp3 &'
alias nsl       'nslookup'
alias rpmw      '/bin/rpm -qf `which \!*`'
alias sshf	'ssh -R 37:localhost:37 -R 873:localhost:873'
alias viw	'vi `which \!*`'
alias x		'setenv DISPLAY \!*\:0'
alias xlocal	'setenv DISPLAY localhost:0.0'
alias xc	'chdir; xclock -digital -update 1 -geometry -0-0 &'
alias xl	'chdir; xload -geometry -0-0 -label '$h' &'
alias xterm	'xterm -bg white -fg black -sb -n '$h
alias xt	'chdir; xterm \!* &'
alias xt25	'xt -geometry 80x25+0+0 \!*'
alias xt50	'xt -geometry 80x50+0+0 \!*'
alias xtitle	'echo "\033]0;\!*\007"'

alias f0	'find . -type f -size 0 -iname "*\!***" | cut -c 3-'
alias f3	'find . -type f '$i' "*.mp3" | cut -c 3-'
alias fd	$d $i' "*\!***" | cut -c 3-'
alias fd1	$d -mindepth 1 -maxdepth 1 $i' "*\!***" | cut -c 3-'
alias fd2	$d -mindepth 2 -maxdepth 2 $i' "*\!***" | cut -c 3-'
alias ff	$f $i' "*\!***" | cut -c 3-'
alias fl	'find . -ilname "*\!***" | cut -c 3-'
alias fm	$f' -mtime "\!*" | cut -c 3-'

unset d
unset f
unset f0
unset h
unset i
unset x0

if ( -e /etc/config/+/cshrc ) then
  source /etc/config/+/cshrc
endif

if ( -e $HOME/.cshrc.`uname` ) then
  source $HOME/.cshrc.`uname`
endif

if ( -e $HOME/.cshrc.`hostname` ) then
  source $HOME/.cshrc.`hostname`
endif